agda-dependencies/flake.nix at main · omelkonian/agda-dependencies · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
{
  description = "Agda dependencies";

  inputs.nixpkgs.url = "github:NixOs/nixpkgs/nixpkgs-unstable";
  inputs.flake-utils.url = "github:numtide/flake-utils";

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
    }:
    let
      agda-dependencies-overlay = final: prev: {
        haskellPackages = prev.haskellPackages.extend (
          hfinal: hprev: {
            agda-dependencies = hprev.callCabal2nix "agda-deps" ./. { };
          }
        );
      };
    in
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs {
          inherit system;
          overlays = [
            agda-dependencies-overlay
          ];
        };
      in
      {
        packages = {
          default = pkgs.haskellPackages.agda-dependencies;
        };

        devShells = {
          default = pkgs.haskellPackages.developPackage {
            root = ./.;
            modifier =
              drv:
              pkgs.haskell.lib.addBuildTools drv (
                with pkgs.haskellPackages;
                [
                  cabal-install
                  haskell-language-server
                  pkgs.xdot
                  pkgs.zlib
                ]
              );
          };
        };
      }
    );
}