nixcon-vouchers/flake.nix at main · nixcon/nixcon-vouchers · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
{
  nixConfig = {
    extra-substituters = "https://cache.ners.ch/haskell";
    extra-trusted-public-keys = "haskell:WskuxROW5pPy83rt3ZXnff09gvnu80yovdeKDw5Gi3o=";
  };

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    servant-effectful = {
      url = "github:Kleidukos/servant-effectful";
      flake = false;
    };
    wai-middleware-auth = {
      url = "github:ners/wai-middleware-auth";
      flake = false;
    };
  };

  outputs = inputs:
    with builtins;
    let
      inherit (inputs.nixpkgs) lib;
      foreach = xs: f: with lib; foldr recursiveUpdate { } (
        if isList xs then map f xs
        else if isAttrs xs then mapAttrsToList f xs
        else throw "foreach: expected list or attrset but got ${typeOf xs}"
      );
      pname = "nixcon-vouchers";
      overlay = lib.composeManyExtensions [
        (final: prev: {
          haskell = prev.haskell // {
            packageOverrides = lib.composeManyExtensions [
              prev.haskell.packageOverrides
              (hfinal: hprev: with prev.haskell.lib.compose; {
                ${pname} = hfinal.callCabal2nix pname ./. { };
                haxl = (unmarkBroken hprev.haxl).overrideAttrs {
                  postPatch = "rm Setup.hs";
                };
                servant-effectful = hfinal.callCabal2nix "servant-effectful" inputs.servant-effectful { };
                wai-middleware-auth = hfinal.callCabal2nix "wai-middleware-auth" inputs.wai-middleware-auth { };
                wreq-effectful = doJailbreak (unmarkBroken hprev.wreq-effectful);
              })
            ];
          };
        })
      ];
    in
    foreach inputs.nixpkgs.legacyPackages
      (system: pkgs':
        let
          pkgs = pkgs'.extend overlay;
          hps = with lib; foldlAttrs
            (acc: name: hp':
              let
                hp = tryEval hp';
                version = getVersion hp.value.ghc;
                majorMinor = versions.majorMinor version;
                ghcName = "ghc${replaceStrings ["."] [""] majorMinor}";
              in
              if hp.value ? ghc && ! acc ? ${ghcName} && versionAtLeast version "9.4" && versionOlder version "9.13"
              then acc // { ${ghcName} = hp.value; }
              else acc
            )
            { default = pkgs.haskellPackages; }
            pkgs.haskell.packages;
        in
        {
          legacyPackages.${system} = pkgs;
          packages.${system}.default = hps.default.${pname};
          devShells.${system} =
            foreach hps (ghcName: hp: {
              ${ghcName} = hp.shellFor {
                packages = ps: [ hp.${pname} ];
                nativeBuildInputs = with pkgs; [
                  dhall-lsp-server
                  haskellPackages.cabal-gild
                  haskellPackages.cabal-install
                  haskellPackages.fourmolu
                  hp.haskell-language-server
                  nixpkgs-fmt
                  treefmt
                ];
              };
            });
          formatter.${system} = pkgs.treefmt;
        }
      ) // {
      overlays.default = overlay;
      nixosModules.default = { config }:
        let
          cfg = config.services.nixcon-contributor-verify;
        in
        {
          options = { };
          config = lib.mkIf cfg.enable { };
        };
    };
}