build.gradle

plugins {
    id 'net.fabricmc.fabric-loom' version '1.17.11'
    id 'maven-publish'
    id 'signing'
    id 'io.github.gradle-nexus.publish-plugin' version '2.0.0'
    id 'checkstyle'
    id 'pmd'
    id 'com.modrinth.minotaur' version '2.9.0'
}

ext {
    checkstyleVersion = '13.6.0'

    pmdVersion = '7.25.0'
}

version = project.mod_version
group = project.maven_group

base {
    archivesName = project.archivesBaseName
}

loom {
    accessWidenerPath = file("src/main/resources/zpral.classtweaker")
    log4jConfigs.from(file("src/dev/log4j2.xml"))
}

// https://github.com/gradle/gradle/issues/27035
configurations.checkstyle {
    resolutionStrategy.capabilitiesResolution.withCapability("com.google.collections:google-collections") {
        select("com.google.guava:guava:0")
    }
}

dependencies {
    checkstyle "com.puppycrawl.tools:checkstyle:${checkstyleVersion}"

    pmd "net.sourceforge.pmd:pmd-ant:${pmdVersion}",
            "net.sourceforge.pmd:pmd-java:${pmdVersion}"

    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    implementation "net.fabricmc:fabric-loader:${project.loader_version}"
    // Required for unfrozen registry
    implementation fabricApi.module("fabric-registry-sync-v0", project.fabric_api_version)

    // Only needed during development
    localRuntime "net.fabricmc.fabric-api:fabric-api:${project.fabric_api_version}"
}

processResources {
    filesMatching("fabric.mod.json") {
        expand "version": project.version,
                "id": project.archivesBaseName,
                "name": project.mod_name,
                "desc": project.mod_desc,
                "license_spdx_id": project.mod_license_spdx_id,
                "minecraft_version": project.minecraft_version,
                "loader_version": project.loader_version,
                "fabric_api_version": project.fabric_api_version
    }
}

checkstyle {
    configDirectory = file("$rootProject.projectDir/.config/checkstyle")
    ignoreFailures = false
    showViolations = true
    toolVersion = checkstyleVersion
}

pmd {
    consoleOutput = true
    incrementalAnalysis = true
    ruleSetFiles = files(".config/pmd/java/ruleset.xml")
    toolVersion = pmdVersion
}

tasks.withType(Checkstyle).configureEach {
    enabled = project.hasProperty("checkstyleEnabled");
}

tasks.withType(Pmd).configureEach {
    enabled = project.hasProperty("pmdEnabled")
}

tasks.withType(JavaCompile).configureEach {
    it.options.release = 25
}

java {
    // Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
    // if it is present.
    withSourcesJar()
    withJavadocJar()

    sourceCompatibility = JavaVersion.VERSION_25
    targetCompatibility = JavaVersion.VERSION_25
}

javadoc {
    def opts = (options as StandardJavadocDocletOptions)
    opts.addBooleanOption('html5', true)
    opts.addBooleanOption('Xdoclint:none', true)
    opts.addBooleanOption('quiet', true)
    opts.tags(
            "apiNote:a:API Note:",
            "implSpec:a:Implementation Requirements:",
            "implNote:a:Implementation Note:"
    )
}

jar {
    from("LICENSE") {
        rename { "${it}_${project.archivesBaseName}"}
    }
}

// configure the maven publication
publishing {
    publications {
        create("mavenJava", MavenPublication) {
            artifactId = project.archivesBaseName
            from components.java
            pom {
                name = project.mod_name
                description = project.mod_desc
                url = 'https://github.com/litetex-oss/mcm-' + artifactId
                licenses {
                    license {
                        name = project.mod_license_spdx_id
                        url = project.mod_license_url
                        distribution = 'repo'
                    }
                }
                developers {
                    developer {
                        name = 'litetex'
                        url = 'https://github.com/litetex'
                    }
                }
                scm {
                    connection = 'scm:git:https://github.com/litetex-oss/' + artifactId + '.git'
                    url = 'https://github.com/litetex-oss/mcm-' + artifactId
                }
            }
        }
    }

    // Docs: https://docs.gradle.org/current/userguide/publishing_maven.html
    // repositories.mavenLocal() // uncomment to publish locally
    if (providers.environmentVariable("MAVEN_PUBLISH_URL").present) {
        repositories.maven {
            url = providers.environmentVariable("MAVEN_PUBLISH_URL")
            credentials {
                username = providers.environmentVariable("MAVEN_PUBLISH_USERNAME").get()
                password = providers.environmentVariable("MAVEN_PUBLISH_PASSWORD").get()
            }
        }
    }
}

tasks.modrinth.dependsOn(tasks.modrinthSyncBody)
// https://github.com/modrinth/minotaur/blob/master/README.md#available-properties
modrinth {
    // token defaults to "MODRINTH_TOKEN" environment variable
    projectId = project.archivesBaseName
    // Default/empty value is release
    versionType = System.getenv("MODRINTH_VERSION_TYPE")
    uploadFile = jar
    additionalFiles = [sourcesJar]
    syncBodyFrom = provider {
        rootProject.file("README.md").text
    }
    changelog = provider {
        def changelogFile = System.getenv("MODRINTH_CHANGELOG_FILE")
        return changelogFile != null
                ? rootProject.file(changelogFile).text
                : System.getenv("MODRINTH_CHANGELOG_TEXT")
    }
    dependencies {
        required.project 'fabric-api'
    }
}

signing {
    required { System.getenv("MAVEN_GPG_PRIVATE_KEY") != null }
    def signingKey = System.getenv("MAVEN_GPG_PRIVATE_KEY")
    def signingPassword = System.getenv("MAVEN_GPG_PASSPHRASE")
    useInMemoryPgpKeys(signingKey, signingPassword)
    sign publishing.publications.mavenJava
}

// Docs: https://github.com/gradle-nexus/publish-plugin
// Publish using publishToSonatype closeAndReleaseSonatypeStagingRepository
nexusPublishing {
    repositories {
        sonatype {
            nexusUrl.set(uri("https://ossrh-staging-api.central.sonatype.com/service/local/"))
            snapshotRepositoryUrl.set(uri("https://central.sonatype.com/repository/maven-snapshots/"))
            username = System.getenv("SONATYPE_MAVEN_CENTRAL_PORTAL_USERNAME")
            password = System.getenv("SONATYPE_MAVEN_CENTRAL_PORTAL_TOKEN")
        }
    }
}