mzpeak/flake.nix at trunk · OpenMS/mzpeak · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
  };

  outputs =
    { self, nixpkgs, ... }:
    let
      # List of supported systems:
      supportedSystems = nixpkgs.lib.platforms.unix;

      # Iterate over each system:
      each =
        f:
        nixpkgs.lib.genAttrs supportedSystems (
          system:
          let
            pkgs = import nixpkgs { inherit system; };
          in
          f pkgs system
        );
    in
    {
      packages = each (
        pkgs: system: {
          default = self.packages.${system}.mzpeak;

          mzpeak = pkgs.callPackage nix/package.nix {
            # Override clang on macOS:
            stdenv = if pkgs.stdenv.isDarwin then pkgs.overrideCC pkgs.stdenv pkgs.clang_22 else pkgs.stdenv;
          };

          # Always use clang.
          mzpeak_clang = self.packages.${system}.mzpeak.override (_: {
            stdenv = pkgs.overrideCC pkgs.stdenv pkgs.clang_22;
          });

          # Build dependencies with debugging symbols.
          mzpeak_debug = self.packages.${system}.mzpeak.override (_: {
            arrow-cpp = pkgs.arrow-cpp.overrideAttrs (orig: {
              cmakeBuildType = "RelWithDebInfo";
              dontStrip = true;
              hardeningDisable = (orig.hardeningDisable or [ ]) ++ [ "fortify" ];
            });
          });
        }
      );

      checks = each (pkgs: system: self.packages.${system});

      devShells = each (
        pkgs: system:
        let
          shell =
            mzpeak:
            pkgs.mkShell {
              name = "mzpeak shell";
              hardeningDisable = [ "fortify" ];
              inputsFrom = [ mzpeak ];
              buildInputs = [
                pkgs.clang-tools
                pkgs.python3
                pkgs.ruff
              ];
            };
        in
        {
          default = shell self.packages.${system}.default;
          debug = shell self.packages.${system}.mzpeak_debug;
        }
      );
    };
}